process TAKE.ORDER given CUSTOMER.ORDER
''
'' AUTHOR: Steve Bailey
'' CREATED: 7-25-90
'' DESCRIPTION:
''     This process simulates a the calling out of an order. 
''

define I as an integer variable
define CUSTOMER.ORDER as a pointer variable

'' call the order out to the knaves
work .CALL.ORDER.TIME .SECONDS
file CUSTOMER.ORDER in ORDER.RACK
display CUSTOMER.ORDER with "order.icn" at 
  (.ORDER.RACKX+N.ORDER.RACK*.3, .ORDER.RACKY)

'' tell knaves to send however many burgers
for I = 1 TO NUM.BURGERS(CUSTOMER.ORDER) do
    activate a MAKE.BURGER now
loop

'' tell knaves to make however many shakes
for I = 1 TO NUM.SHAKES(CUSTOMER.ORDER) do
    activate a MAKE.SHAKE now
loop

'' tell knaves to make fries
for I = 1 to NUM.FRIES(CUSTOMER.ORDER) do
    activate a MAKE.FRY now
loop

return
end
