#! /bin/csh -f
# Shell script to set FMHOME in the .profile, and .login files
# in the Frame Demo Account.
# $Header: /xdim/dim40/fmhome/fminit/samplehome/RCS/demo_install,v 1.2 1993/06/28 21:28:41 kty Exp $

# Determine FMHOME.
set arg0=$0
set mydir=$arg0:h
set myname=$arg0:t

# The ':h' did not strip anything.
if ("X$mydir" == "X$myname") then
    set mydir=''
endif

# Strip off any trailing '/fminit/samplehome'.
if ("$mydir" =~ */fminit/samplehome) then
    set mydir=$mydir:h
    set mydir=$mydir:h
endif

set cdir=$cwd  ;# Don't muck with the C-shell builtin var '$cwd'!
# Strip off any trailing '/fminit/samplehome' from '$cdir'.
if ("$cdir" =~ */fminit/samplehome) then
    set cdir=$cdir:h
    set cdir=$cdir:h
endif

if ("$mydir" =~ /*) then
    # Typical case <install_dir>/fminit/samplehome.
    set FMHOME=$mydir

else if ((-e "./fminit/samplehome/$myname") || (-e "./$myname")) then
    # User is either in '$FMHOME' or '$FMHOME/fminit/samplehome'
    set FMHOME=$cdir

else if ((-e "$mydir/fminit/samplehome/$myname") || (-e "$mydir/$myname")) then
    # A relative path.
    set FMHOME=$cdir/$mydir

else
    echo "Cannot determine FMHOME\! Contact Frame Technical Support."
endif

foreach i (login profile)
  if (-e $i) then
    echo "Fixing $i."
    sed -e "s:<FrameMaker_install_dir>:${FMHOME}:" < $i > /tmp/$i.$$
    mv $i $i.orig
    mv /tmp/$i.$$ $i
#    sed -e "s:\(FMHOME[ 	]*=[ 	]*\)[^;]*:\1${FMHOME}:" \
#	-e "s:\(setenv[ 	]*FMHOME[ 	]*\)[^;]*:\1${FMHOME}:" < $i
  endif
end
